Spawn a ped

Spawning a ped (also called character or actor) is not as simple as inserting one line. There are steps that need to be taken in order to successfully spawn a ped. This tutorial will show you the basic steps of spawning a ped using a format used in Sanny Builder. These examples are for San Andreas but with minor tweaks can be used for GTA III and Vice City.

Create your script

First, create a script. Here is an example:

004F: create_thread @spawn_ped

:spawn_ped
// add code from tutorial here
004E: end_thread

Load your model

It is very important that the model of your ped has been loaded into the game. If your create a ped with an unavailable model, the game will crash. You can find a list of all peds available to use in the default.ide file for GTA III and Vice City or the peds.ide file for San Andreas. The script uses the ped's IDE number but Sanny Builder supports using the ped's model name with a hash character. Let's try the first ped in the list, BFORI.

0247: request_model #BFORI
038B: load_requested_models

An alternative way to load the models involves more code but the game would not pause for the models to load like the code above. It uses an IF statement with the conditional opcode 0248.

repeat
    wait 0 ms
    if
        0248:   model #BFORI available
    then
        break
    end
until false

There are some ped-spawning opcodes that do not require the ped's model to be explicitly loaded. See below for more information.

Create your ped

Now you can use the primary opcode to create a ped: 009A. The opcode includes the ped's pedtype and the coordinate to spawn the ped. Sanny Builder has a built-in coordinates tool. Go to Tools>IDE Tools>Coords manager... or use the shortcut Ctrl+Alt+1 while the game is running. This will show the current position of your player character.

009A: 0@ = create_actor_pedtype 4 model #BFORI at 0.0 0.0 0.0

Other opcodes

There are other opcodes that also spawn a ped in different situations, including:

• 0129, creates a ped as a driver in a vehicle.
• 01C8, creates a ped as a passenger in a vehicle.

There are opcodes that can spawn a random ped without the need to request the model of the ped.

• 0376, creates a random ped.
• 0560, creates a random ped as a driver in a vehicle.
• 0561, creates a random ped as a passenger in a vehicle.

Ped type limitation

Some pedtypes are limited to be compatible to specific models or else the game may crash.

• Pedtype 6 can only be used with models between 0 and 4 (#null, #cop, #swat, #fbi, #army).
• Pedtype 16 can only be used with model 5 (#medic).
• Pedtype 17 can only be used with model 6 (#fireman).

Release your model

After the ped is created and the model is no longer needed, release it using opcode 0249.

0249: release_model #BFORI

Set your ped

You can now add settings and attributes to your ped, like rotating your ped or adding animations to your ped. The variable 0@ is the handle of your ped, like an identifier. Use this variable when using opcodes specific to your ped. You can search these opcodes by using Sanny Builder's Opcode Search Tool. Go to Tools>IDE Tools>Opcode Search... or use the shortcut Ctrl+Alt+2. Then type actor in the search box to find a list of named opcodes related to it. When you no longer need the ped, mark it as no longer needed using opcode 01C2 so that the game can remove the ped for you.

Full example

:spawn_ped
// load model, required to prevent unnecessary crash!
0247: request_model #BFORI
038B: load_requested_models
// spawn character
009A: 0@ = create_actor 4 #BFORI at 0.0 0.0 0.0
// cleanup
0249: release_model #BFORI
01C2: mark_actor_as_no_longer_needed 0@
004E: end_thread

External links

• Screenshots of all ped models in GTA III
• Screenshots of all ped models in Vice City