0392

   SET_OBJECT_DYNAMIC

---

Description

Sets the object's ability to be dynamic

Syntax

0392: object [object handle] toggle_in_moving_list [int]

Parameter

[object handle]

The handle of the object

[int]

0 = not dynamic, 1 = dynamic

Native analog

SET_OBJECT_DYNAMIC

This opcode sets the object's ability to be dynamic in the environment. This opcode only affects dynamic objects and has no effect on static ones. By default, when dynamic objects are created using either opcode 0107 or 029B, gravity will not affect the object and will float in the air unless acted upon by the environment. Enabling dynamics through this opcode will allow gravity to affect the object and allow it to drop onto the ground. Disabling dynamics will stop gravity and all environmental effects from affecting the object at that moment; the object can still be affected by the environment and will not be static.

Example

The following example spawns a dynamic object above the player (a pizza box for Vice City in this example). The object will only be affected by gravity and the environment when holding button 13 (CAMERA key). Otherwise, gravity and the environment is forced to have no effect on the object and the box will be stuck floating in the air. If the object is about to hit the ground, it is warped back up to resume the fall.

// set constants
const
OBJECT_MODEL = #PIZZABOX
OBJECT_HANDLE = 0@
OBJECT_MARKER = 1@
POS_X = 2@
POS_Y = 3@
POS_Z = 4@
HEIGHT = 5@
end

// spawn object
00A0: store_actor $PLAYER_ACTOR position_to POS_X POS_Y POS_Z
POS_Z += 20.0
0107: OBJECT_HANDLE = create_object OBJECT_MODEL at POS_X POS_Y POS_Z
0188: OBJECT_MARKER = create_marker_above_object OBJECT_HANDLE
0382: set_object OBJECT_HANDLE collision_detection 1

while if 03CA:   object OBJECT_HANDLE exists
    wait 10
    01BB: store_object OBJECT_HANDLE position_to POS_X POS_Y POS_Z
    02CE: HEIGHT = ground_z POS_X POS_Y POS_Z
    0063: POS_Z -= HEIGHT
    if
        POS_Z < 5.0
    then
        POS_Z += 50.0
        01BC: put_object OBJECT_HANDLE at POS_X POS_Y POS_Z
    end
    if
        00E1:   key_pressed 0 13  // camera key
    then
        0392: object OBJECT_HANDLE toggle_in_moving_list 1  // if key is held, box will fall
    else
        0392: object OBJECT_HANDLE toggle_in_moving_list 0  // if key is not held, box will not fall
    end
end

Keywords

set, toggle, object, movable, move, dynamic