Moving gate

This is a code snippet of a moving gate in Sanny Builder's format and should work in GTA III, Vice City, and San Andreas. This code is based on the moving gates, including the sound it makes, in GTA III. Remember to read the tutorial on how to create a thread before proceeding to implement this code.

// set constants
const
OBJECT = #ELECTRICGATE // you can use any object you want but make sure it's valid
                       //  use object's IDE number in CLEO instead
INITI_X = 298.0        // initial x position
INITI_Y = -313.6       // initial y position
INITI_Z = 11.0         // initial z position
ANGLE = 0.0            // angle of your gate
FINAL_X = 304.0        // final x position
FINAL_Y = -313.6       // final y position
FINAL_Z = 11.0         // final z position

gate_sfx1 = 1@
not_clunked_yet = 2@
gate_sfx2 = 3@
objectx = 4@
objecty = 5@
objectz = 6@
end

// create gate object
029B: 0@ = init_object OBJECT at INITI_X INITI_Y INITI_Z
01C7: remove_object_from_mission_cleanup_list 0@
0177: set_object 0@ z_angle_to ANGLE

while true
    wait 250 ms
    if
        0256:   player $PLAYER_CHAR defined
    then
        if
            // use other area check opcodes for more precision and options
            00FE:   actor $PLAYER_ACTOR in_sphere 0 near_point INITI_X INITI_Y INITI_Z radius 5.0 5.0 5.0
        then
            if
                gate_sfx1 == 0
            then
                //018C: play_sound 92 at INITI_X INITI_Y INITI_Z // uncomment for III
                //018C: play_sound 3 at INITI_X INITI_Y INITI_Z  // uncomment for VC
                //097B: play_audio_at_object 0@ event 1100       // uncomment for SA
                gate_sfx1 = 1
            end
            while if 834E:   not move_object 0@ to FINAL_X FINAL_Y FINAL_Z speed 0.1 0.1 0.0 flag 0
                wait 0 ms
            end
            if
                not_clunked_yet == 1
            then
                gate_sfx2 = 0
                not_clunked_yet = 0
            end
            if
                gate_sfx2 == 0
            then
                //018C: play_sound 93 at FINAL_X FINAL_Y FINAL_Z // uncomment for III
                //018C: play_sound 3 at FINAL_X FINAL_Y FINAL_Z  // uncomment for VC
                //097B: play_audio_at_object 0@ event 1101       // uncomment for SA
                gate_sfx2 = 1
            end
        else
            if
                gate_sfx1 == 1
            then
                //018C: play_sound 92 at FINAL_X FINAL_Y FINAL_Z // uncomment for III
                //018C: play_sound 3 at FINAL_X FINAL_Y FINAL_Z  // uncomment for VC
                //097B: play_audio_at_object 0@ event 1100       // uncomment for SA
            end
            while if 834E:   not move_object 0@ to INITI_X INITI_Y INITI_Z speed 0.1 0.1 0.0 flag 1
                wait 0 ms
            end
            01BB: store_object 0@ position_to objectx objecty objectz
            if
                gate_sfx2 == 1
            then
                not_clunked_yet = 1
                if and
                    objectx == INITI_X
                    objecty == INITI_Y
                    objectz == INITI_Z
                then
                    //018C: play_sound 93 at INITI_X INITI_Y INITI_Z // uncomment for III
                    //018C: play_sound 3 at INITI_X INITI_Y INITI_Z  // uncomment for VC
                    //097B: play_audio_at_object 0@ event 1101       // uncomment for SA
                    gate_sfx2 = 0
                    not_clunked_yet = 0
                end
                gate_sfx1 = 0
            end
        end
    end
end