0129

   CREATE_CHAR_INSIDE_CAR

---

Description

Spawns a character in the driver seat of a vehicle

Syntax

0129: [var] = create_actor_pedtype [int1] model [int2] in_car [car handle] driverseat

Parameter

[car handle]

The handle of the vehicle

[int1]

Ped type

[int2]

Valid character model ID number as defined in the PEDS section of the IDE file; also acceptable is model's DFF name with a hash character

[var]

Variable to store the handle of the character

Native analog

CREATE_CHAR_INSIDE_CAR

This opcode spawns a character in the driver seat of a vehicle. Using this opcode requires an existing vehicle and opcode 0247 to load the character model or else the game could crash.

Example

See also: Spawn a ped

The following example, using Sanny Builder, will spawn a ped in a car close to the player character.

// set constants
const
CHAR_MODEL = #BFORI
CAR_MODEL = #PONY
CHAR_HANDLE = 0@
CAR_HANDLE = 1@
X_POS = 2@
Y_POS = 3@
Z_POS = 4@
end

// load model, required to prevent unnecessary crash!
0247: request_model CHAR_MODEL
0247: request_model CAR_MODEL
// check if model is loaded
repeat
    wait 0
    if and
        0248:   model CHAR_MODEL available
        0248:   model CAR_MODEL available
    then
        break
    end
until false
// spawn car
00A0: store_actor $PLAYER_ACTOR position_to X_POS Y_POS Z_POS
X_POS += 4.0
00A5: CAR_HANDLE = create_car CAR_MODEL at X_POS Y_POS Z_POS
// spawn character
0129: CHAR_HANDLE = create_actor_pedtype 4 model CHAR_MODEL in_car CAR_HANDLE driverseat
// cleanup
0249: release_model CHAR_MODEL
0249: release_model CAR_MODEL
01C2: remove_references_to_actor CHAR_HANDLE
01C3: remove_references_to_car CAR_HANDLE

Keywords

create, spawn, actor, ped, pedestrian, character, pedtype, model, vehicle, car, driver